Please Note: This article is written for users of the following Microsoft Word versions: 2007, 2010, 2013, 2016, 2019, and Word in Microsoft 365. If you are using an earlier version (Word 2003 or earlier), this tip may not work for you. For a version of this tip written specifically for earlier versions of Word, click here: Using Sequential Document Serial Numbers.

Using Sequential Document Serial Numbers

Written by Allen Wyatt (last updated July 31, 2021)
This tip applies to Word 2007, 2010, 2013, 2016, 2019, and Word in Microsoft 365


If you have a need to create serial numbers in your documents and they are very simple in nature, you can do so using a macro. This approach to serial numbers is great if your serial numbers are sequential (1, 2, 3, etc.) or regular in their incidence (3, 5, 7, etc.).

To begin, you should create the macro that will control the changing of the serial number and the printing of your document. You can use the following macro:

Sub MySerial()
    Dim docCurrent As Document
    Dim rSerial As Range
    Dim iSerialNum As Integer
    Dim sTemp As String
    Dim iCopies As Integer
    Dim iCount As Integer

    Set docCurrent = Application.ActiveDocument
    Set rSerial = docCurrent.Bookmarks("Serial").Range

    ' Get the starting number. Note that the serial number
    ' needs to consist only of digits (no leading letters or
    ' symbols) in order for the Val function to work properly.
    iSerialNum = Val(rSerial.Text)

    ' Get the number of copies required
    sTemp = InputBox("How many copies?", "Print Serialized", "1")
    iCopies = Val(sTemp)

    For iCount = 1 To iCopies
        ' Print the document
        docCurrent.PrintOut Range:=wdPrintAllDocument
        ' Increment the serial number
        iSerialNum = iSerialNum + 1
        ' Convert to formatted number (with leading zeroes)
        ' and put back into the document.
        sTemp = Format(iSerialNum, "00000")
        rSerial.Text = sTemp
    Next iCount

    ' Reset the bookmark, since the updating procedure
    ' wipes out the old one.
    docCurrent.Bookmarks.Add Name:="Serial", Range:=rSerial
End Sub

There is only one prerequisite to using the macro: you need to make sure that your document contains a bookmark named Serial. This bookmark should reference the serial number in your document, as you want it to appear in the first printed document. The macro assumes that the serial number will be something like "00010" or "00123", with the leading zeroes. Thus, your bookmark (Serial) should reference the five digits that constitute your serial number.

If you want your serial number to be formatted differently, then you'll need to change the macro. Don't forget that the macro assumes the serial number can be converted directly to a value that can be incremented. So, if your bookmarked serial number starts with a letter (such as "Copy 001"), that will never increment properly. Instead, bookmark only the numeric portion.

When you are through running the macro, you can save the document and the serial number will be ready for the next time you want to use it.

Note:

If you would like to know how to use the macros described on this page (or on any other page on the WordTips sites), I've prepared a special page that includes helpful information. Click here to open that special page in a new browser tab.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (9540) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, and Word in Microsoft 365. You can find a version of this tip for the older menu interface of Word here: Using Sequential Document Serial Numbers.

Author Bio

Allen Wyatt

With more than 50 non-fiction books and numerous magazine articles to his credit, Allen Wyatt is an internationally recognized author. He is president of Sharon Parq Associates, a computer and publishing services company. ...

MORE FROM ALLEN

Formatting for Hundredths of Seconds

When you display a time in a cell, Excel normally displays just the hours, minutes, and seconds. If you want to display ...

Discover More

Forcing Input to Uppercase

If you type information into a workbook, you may want to make sure that what you type is always stored in uppercase. ...

Discover More

Modifying What is Started when You Start Windows

Did you know that Windows automatically starts extra programs whenever you boot your system? If you want to see which ...

Discover More

The First and Last Word on Word! Bestselling For Dummies author Dan Gookin puts his usual fun and friendly candor back to work to show you how to navigate Word 2013. Spend more time working and less time trying to figure it all out! Check out Word 2013 For Dummies today!

More WordTips (ribbon)

Understanding Background Printing

We click the button to print our document and seldom think of what is happening behind the scenes. Word prints documents, ...

Discover More

Adding a Horizontal Watermark with a PostScript Printer

In Windows, printer drivers translate formatting into a printer control language, like PostScript, that the printer ...

Discover More

Printing Show/Hide Characters

Non-printing characters are very handy to view when editing a document. But what if you want those characters to no ...

Discover More
Subscribe

FREE SERVICE: Get tips like this every week in WordTips, a free productivity newsletter. Enter your address and click "Subscribe."

View most recent newsletter.

Comments

If you would like to add an image to your comment (not an avatar, but an image to help in making the point of your comment), include the characters [{fig}] (all 7 characters, in the sequence shown) in your comment text. You’ll be prompted to upload your image when you submit the comment. Maximum image size is 6Mpixels. Images larger than 600px wide or 1000px tall will be reduced. Up to three images may be included in a comment. All images are subject to review. Commenting privileges may be curtailed if inappropriate images are posted.

What is five more than 3?

There are currently no comments for this tip. (Be the first to leave your comment—just use the simple form above!)


This Site

Got a version of Word that uses the ribbon interface (Word 2007 or later)? This site is for you! If you use an earlier version of Word, visit our WordTips site focusing on the menu interface.

Videos
Subscribe

FREE SERVICE: Get tips like this every week in WordTips, a free productivity newsletter. Enter your address and click "Subscribe."

(Your e-mail address is not shared with anyone, ever.)

View the most recent newsletter.